【原】通達(dá)信短線布局指標(biāo)公式（附源碼破譯、源碼和使用說(shuō)明）

追夢(mèng)文庫(kù) 2023-10-16 發(fā)布于湖北

展開(kāi)全文

編程思路破譯

LC賦值:1日前的收盤(pán)價(jià)

RSI5賦值:(((收盤(pán)價(jià)-LC)和0的較大值的5日[1日權(quán)重]移動(dòng)平均 / (收盤(pán)價(jià)-LC)的絕對(duì)值的5日[1日權(quán)重]移動(dòng)平均) * 100)

TTR賦值:(最高價(jià)-最低價(jià))和(最高價(jià)-1日前的收盤(pán)價(jià))的絕對(duì)值的較大值和(最低價(jià)-1日前的收盤(pán)價(jià))的絕對(duì)值的較大值的10日累和

HD賦值:(最高價(jià) - 1日前的最高價(jià))

LD賦值:(1日前的最低價(jià) - 最低價(jià))

DMP賦值:如果((HD>0)AND(HD>LD)),返回HD,否則返回0的10日累和

DMM賦值:如果((LD>0)AND(LD>HD)),返回LD,否則返回0的10日累和

PDI賦值:((DMP * 100) / TTR)

MDI賦值:((DMM * 100) / TTR)

ADX賦值:(((MDI-PDI)的絕對(duì)值/(MDI+PDI))*100)的5日簡(jiǎn)單移動(dòng)平均

AV賦值:(RSI5 + ADX)

DXR賦值:(((ADX + 5日前的ADX) / 2) + RSI5)

WR10賦值:((100 * (10日內(nèi)最高價(jià)的最高值 - 收盤(pán)價(jià))) / (10日內(nèi)最高價(jià)的最高值 - 10日內(nèi)最低價(jià)的最低值))

NEWVOL賦值:(RSI5 - WR10)

底賦值:(AV + NEWVOL),VOLSTICK

底5賦值:底的5日簡(jiǎn)單移動(dòng)平均,畫(huà)深灰色

趨勢(shì)線賦值:1日內(nèi)底的最低值,COLORFFFFFF

當(dāng)滿足條件(趨勢(shì)線>230)時(shí),在250和趨勢(shì)線位置之間畫(huà)柱狀線,寬度為0.8,1不為0則畫(huà)空心柱.,線寬為6,畫(huà)綠色

AA賦值:1日前的收盤(pán)價(jià)

BBB賦值:收盤(pán)價(jià)-AA和0的較大值的21日[1日權(quán)重]移動(dòng)平均/收盤(pán)價(jià)-AA的絕對(duì)值的21日[1日權(quán)重]移動(dòng)平均*1000

HHH賦值:BBB-27日內(nèi)BBB的最低值

CCC賦值:27日內(nèi)BBB的最低值-BBB

SS賦值:(CCC的2日簡(jiǎn)單移動(dòng)平均*3+CCC*13)/16

輸出G3:HHH的3日簡(jiǎn)單移動(dòng)平均,畫(huà)黃色

G6賦值:HHH的6日簡(jiǎn)單移動(dòng)平均,畫(huà)洋紅色

G8賦值:HHH的8日簡(jiǎn)單移動(dòng)平均,線寬為1,畫(huà)綠色

QQ賦值:(HHH的5日簡(jiǎn)單移動(dòng)平均*3+HHH*13)/16,畫(huà)黃色,線寬為1,DOTLINE

MM賦值:CCC的5日簡(jiǎn)單移動(dòng)平均

WW賦值:如果QQ<G8,返回SS,否則返回MM

EE賦值:如果SS<MM,返回G8,否則返回QQ

實(shí)量賦值:成交量(手),畫(huà)黃色,NODRAW

成交量額賦值:(成交額(元)+成交量(手))/2,VOLSTICK

量賦值:成交量(手)/1日前的成交量(手)>1.8

凈CXH1賦值:成交量(手)/((最高價(jià)-最低價(jià))*2-收盤(pán)價(jià)-開(kāi)盤(pán)價(jià)的絕對(duì)值)

買(mǎi)盤(pán)賦值:如果收陽(yáng)線,返回凈CXH1*(最高價(jià)-最低價(jià)),否則返回如果收陰線,返回凈CXH1*((最高價(jià)-開(kāi)盤(pán)價(jià))+(收盤(pán)價(jià)-最低價(jià))),否則返回成交量(手)/2,畫(huà)紅色,NODRAW

賣(mài)盤(pán)賦值:-如果收陽(yáng)線,返回0-凈CXH1*((最高價(jià)-收盤(pán)價(jià))+(開(kāi)盤(pán)價(jià)-最低價(jià))),否則返回如果收陰線,返回0-凈CXH1*(最高價(jià)-最低價(jià)),否則返回0-成交量(手)/2,畫(huà)綠色,NODRAW

凈買(mǎi)賦值:(買(mǎi)盤(pán)-賣(mài)盤(pán)),VOLSTICK

CXH2賦值:(最高價(jià)-最低價(jià))

CXH3賦值:(開(kāi)盤(pán)價(jià)-收盤(pán)價(jià))的絕對(duì)值

CXH4賦值:(最高價(jià)-如果(收陽(yáng)線),返回收盤(pán)價(jià),否則返回開(kāi)盤(pán)價(jià))

CXH5賦值:(如果(收陽(yáng)線),返回開(kāi)盤(pán)價(jià),否則返回收盤(pán)價(jià)-最低價(jià))

CXH6賦值:((CXH3/CXH2)*成交量(手))

CXH7賦值:((CXH4/CXH2)*成交量(手))

CXH8賦值:((CXH5/CXH2)*成交量(手))

CXH9賦值:如果((成交量(手)/當(dāng)前流通股本(手))>0.001),返回1,否則返回((成交量(手)/當(dāng)前流通股本(手))*100)的對(duì)數(shù)的絕對(duì)值的指數(shù)

CXHA賦值:(((收盤(pán)價(jià)-收盤(pán)價(jià)的5日簡(jiǎn)單移動(dòng)平均)/收盤(pán)價(jià)的5日簡(jiǎn)單移動(dòng)平均)*100)

進(jìn)QQ賦值:CXH6>=CXH7 AND CXH6>= CXH8 AND 收陰線

進(jìn)MMM賦值:收盤(pán)價(jià)<收盤(pán)價(jià)的5日指數(shù)移動(dòng)平均 AND 進(jìn)QQ

進(jìn)JJJ賦值:收盤(pán)價(jià)>=收盤(pán)價(jià)的5日指數(shù)移動(dòng)平均 AND 進(jìn)QQ

進(jìn)JJ賦值:CXH6>=CXH7 AND CXH6>=CXH8 AND 收陽(yáng)線

進(jìn)XX賦值:CXH8>CXH6 AND CXH8>CXH7

進(jìn)MM賦值:CXH7>CXH6 AND CXH7>CXH8

量AA賦值:成交量(手)/((最高價(jià)-最低價(jià))*2-收盤(pán)價(jià)-開(kāi)盤(pán)價(jià)的絕對(duì)值)

買(mǎi)量賦值:如果收陽(yáng)線,返回量AA*(最高價(jià)-最低價(jià)),否則返回如果收陰線,返回量AA*((最高價(jià)-開(kāi)盤(pán)價(jià))+(收盤(pán)價(jià)-最低價(jià))),否則返回成交量(手)/2

賣(mài)量賦值:如果收陽(yáng)線,返回0-量AA*((最高價(jià)-收盤(pán)價(jià))+(開(kāi)盤(pán)價(jià)-最低價(jià))),否則返回如果收陰線,返回0-量AA*(最高價(jià)-最低價(jià)),否則返回0-成交量(手)/2

輸出進(jìn)出量:買(mǎi)量+賣(mài)量,NODRAW

輸出凈量:進(jìn)出量+賣(mài)量,NODRAW

昨日凈量賦值:1日前的凈量

輸出凈量比:進(jìn)出量/凈量,畫(huà)洋紅色,NODRAW

額賦值:成交額(元)/100000000,VOLSTICK,COLORFF00FF

額CXH1賦值:成交額(元)/((最高價(jià)-最低價(jià))*2-收盤(pán)價(jià)-開(kāi)盤(pán)價(jià)的絕對(duì)值)

流入億賦值:如果收陽(yáng)線,返回額CXH1*(最高價(jià)-最低價(jià)),否則返回如果收陰線,返回額CXH1*((最高價(jià)-開(kāi)盤(pán)價(jià))+(收盤(pán)價(jià)-最低價(jià))),否則返回成交額(元)/2/100000000,畫(huà)紅色,NODRAW

流出億賦值:如果收陽(yáng)線,返回0-額CXH1*((最高價(jià)-收盤(pán)價(jià))+(開(kāi)盤(pán)價(jià)-最低價(jià))),否則返回如果收陰線,返回0-額CXH1*(最高價(jià)-最低價(jià)),否則返回0-成交額(元)/2/100000000,畫(huà)洋紅色,NODRAW

差億賦值:流入億+流出億,COLORFFFF00,NODRAW

凈賦值:差億的2日指數(shù)移動(dòng)平均的2日指數(shù)移動(dòng)平均,COLOR00FFFF,NODRAW

WWWCXH99COM賦值:凈的2日指數(shù)移動(dòng)平均

凈1賦值:凈的2日指數(shù)移動(dòng)平均

流賦值:凈1的7日指數(shù)移動(dòng)平均

輸出凈流:3*凈1+流的2日指數(shù)移動(dòng)平均,畫(huà)紅色,NODRAW

輸出五日量額比:成交量額/1日前的成交量額的5日簡(jiǎn)單移動(dòng)平均,畫(huà)洋紅色,NODRAW

跌停賦值:收盤(pán)價(jià)<=計(jì)算跌停價(jià)

當(dāng)滿足條件(底>=0)AND凈買(mǎi)>=0時(shí),在0和底位置之間畫(huà)柱狀線,寬度為0.6,0不為0則畫(huà)空心柱.,線寬為2,畫(huà)黃色

當(dāng)滿足條件進(jìn)出量<0AND凈買(mǎi)<0時(shí),在0和底位置之間畫(huà)柱狀線,寬度為3.2,0不為0則畫(huà)空心柱.,COLOR006600

當(dāng)滿足條件進(jìn)出量<0AND凈買(mǎi)<0時(shí),在0和底位置之間畫(huà)柱狀線,寬度為2.6,0不為0則畫(huà)空心柱.,COLOR008800

當(dāng)滿足條件進(jìn)出量<0AND凈買(mǎi)<0時(shí),在0和底位置之間畫(huà)柱狀線,寬度為1.9,0不為0則畫(huà)空心柱.,COLOR00AA00

當(dāng)滿足條件進(jìn)出量<0AND凈買(mǎi)<0時(shí),在0和底位置之間畫(huà)柱狀線,寬度為1.1,0不為0則畫(huà)空心柱.,COLOR00CC00

當(dāng)滿足條件進(jìn)出量<0AND凈買(mǎi)<0時(shí),在0和底位置之間畫(huà)柱狀線,寬度為0.3,0不為0則畫(huà)空心柱.,COLOR00FF00

當(dāng)滿足條件進(jìn)MMMOR跌停時(shí),在0和底位置之間畫(huà)柱狀線,寬度為0.0,0不為0則畫(huà)空心柱.,畫(huà)綠色

當(dāng)滿足條件進(jìn)MMMOR跌停時(shí),在0和底位置之間畫(huà)柱狀線,寬度為3.1,0不為0則畫(huà)空心柱.,COLORFF0000

當(dāng)滿足條件進(jìn)MMMOR跌停時(shí),在0和底位置之間畫(huà)柱狀線,寬度為1.9,0不為0則畫(huà)空心柱.,COLORFF0000

當(dāng)滿足條件進(jìn)MMMOR跌停時(shí),在0和底位置之間畫(huà)柱狀線,寬度為0.1,0不為0則畫(huà)空心柱.,COLORFFFF00

當(dāng)滿足條件凈買(mǎi)>=0AND進(jìn)JJ>=1AND底<0時(shí),在0和底位置之間畫(huà)柱狀線,寬度為2.3,0不為0則畫(huà)空心柱.,COLOR880088

當(dāng)滿足條件凈買(mǎi)>=0AND進(jìn)JJ>=1AND底<0時(shí),在0和底位置之間畫(huà)柱狀線,寬度為1.6,0不為0則畫(huà)空心柱.,COLORAA00AA

當(dāng)滿足條件凈買(mǎi)>=0AND進(jìn)JJ>=1AND底<0時(shí),在0和底位置之間畫(huà)柱狀線,寬度為0.8,0不為0則畫(huà)空心柱.,COLORCC00CC

當(dāng)滿足條件凈買(mǎi)>=0AND進(jìn)JJ>=1AND底<0時(shí),在0和底位置之間畫(huà)柱狀線,寬度為0.1,0不為0則畫(huà)空心柱.,COLOREE00EE

當(dāng)滿足條件凈買(mǎi)>=0AND底>=0AND底>=1日前的底時(shí),在0和底位置之間畫(huà)柱狀線,寬度為3.2,0不為0則畫(huà)空心柱.,COLOR0000BB

當(dāng)滿足條件凈買(mǎi)>=0AND底>=0AND底>=1日前的底時(shí),在0和底位置之間畫(huà)柱狀線,寬度為1.3,0不為0則畫(huà)空心柱.,COLOR2233DD

當(dāng)滿足條件凈買(mǎi)>=0AND底>=0AND底>=1日前的底時(shí),在0和底位置之間畫(huà)柱狀線,寬度為0.3,0不為0則畫(huà)空心柱.,COLOR6677FF

當(dāng)滿足條件凈買(mǎi)>=0AND底>=0AND底>=1日前的底AND凈流>=1日前的凈流時(shí),在0和底位置之間畫(huà)柱狀線,寬度為0.1,0不為0則畫(huà)空心柱.,畫(huà)黃色

當(dāng)滿足條件(G6>G8OR(G8<50ANDG3>G6ANDG6>1日前的G6))AND凈買(mǎi)>=0ANDG3>1日前的G3AND底5>1日前的底5AND量時(shí),在0和底位置之間畫(huà)柱狀線,寬度為2.3,0不為0則畫(huà)空心柱.,畫(huà)洋紅色

輸出AMV1:G3,畫(huà)紅色,線寬為2

輸出AMV2:G3的2日[1日權(quán)重]移動(dòng)平均,畫(huà)黃色,線寬為2

輸出AMV3:AMV2的2日[1日權(quán)重]移動(dòng)平均,畫(huà)綠色,線寬為2

程序源碼

短線布局:

LC:=REF(CLOSE,1);

RSI5:=((SMA(MAX((CLOSE - LC),0),5,1) / SMA(ABS((CLOSE - LC)),5,1)) * 100);

TTR:=SUM(MAX(MAX((HIGH - LOW),ABS((HIGH - REF(CLOSE,1)))),ABS((LOW - REF(CLOSE,1)))),10);

HD:=(HIGH - REF(HIGH,1));

LD:=(REF(LOW,1) - LOW);

DMP:=SUM(IF(((HD > 0) AND (HD > LD)),HD,0),10);

DMM:=SUM(IF(((LD > 0) AND (LD > HD)),LD,0),10);

PDI:=((DMP * 100) / TTR);

MDI:=((DMM * 100) / TTR);

ADX:=MA(((ABS((MDI - PDI)) / (MDI + PDI)) * 100),5);

AV:=(RSI5 + ADX);DXR:=(((ADX + REF(ADX,5)) / 2) + RSI5);{0,COLORFF00FF;}

WR10:=((100 * (HHV(HIGH,10) - CLOSE)) / (HHV(HIGH,10) - LLV(LOW,10)));

NEWVOL:=(RSI5 - WR10);

底:=(AV + NEWVOL),VOLSTICK;

底5:=MA(底,5),COLORGRAY;

趨勢(shì)線:=LLV(底,1),COLORFFFFFF;STICKLINE((趨勢(shì)線 >230 ),250,趨勢(shì)線,0.8,1),LINETHICK6,COLORGREEN;

AA:=REF(CLOSE,1);

BBB:=SMA(MAX(CLOSE-AA,0),21,1)/SMA(ABS(CLOSE-AA),21,1)*1000;

HHH:=BBB-LLV(BBB,27);

CCC:=LLV(BBB,27)-BBB;

SS:=(MA(CCC,2)*3+CCC*13)/16;

G3:MA(HHH,3),COLORYELLOW;

G6:=MA(HHH,6),COLORMAGENTA;

G8:=MA(HHH,8),LINETHICK1,COLORGREEN;{原值 5}

QQ:=(MA(HHH,5)*3+HHH*13)/16,COLORYELLOW,LINETHICK1,DOTLINE;

{原值 2}

MM:=MA(CCC,5);

WW:=IF(QQ<G8 ,SS,MM);

EE:=IF(SS<MM ,G8,QQ);

實(shí)量:=V,COLORYELLOW,NODRAW;

成交量額:=(AMOUNT+V)/2,VOLSTICK;量:=V/REF(V,1)>1.8;

凈cxh1:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));

買(mǎi)盤(pán):=IF(CLOSE>OPEN,凈cxh1*(HIGH-LOW),IF(CLOSE<OPEN,凈cxh1*((HIGH-OPEN)+(CLOSE-LOW)),VOL/2)),COLORRED,NODRAW;

賣(mài)盤(pán):=-IF(CLOSE>OPEN,0-凈cxh1*((HIGH-CLOSE)+(OPEN-LOW)),IF(CLOSE<OPEN,0-凈cxh1*(HIGH-LOW),0-VOL/2)),COLORGREEN,NODRAW;

凈買(mǎi):=(買(mǎi)盤(pán)-賣(mài)盤(pán)),VOLSTICK;

cxh2:=(HIGH-LOW);

cxh3:=ABS((OPEN-CLOSE));

cxh4:=(HIGH-IF((CLOSE>OPEN),CLOSE,OPEN));

cxh5:=(IF((CLOSE>OPEN),OPEN,CLOSE)-LOW);

cxh6:=((cxh3/cxh2)*VOL);

cxh7:=((cxh4/cxh2)*VOL);

cxh8:=((cxh5/cxh2)*VOL);

cxh9:=IF(((VOL/CAPITAL) >0.001),1,EXP(ABS(LOG(((VOL/CAPITAL)*100)))));

cxhA:=(((CLOSE-MA(CLOSE,5))/MA(CLOSE,5))*100);

進(jìn)QQ:=cxh6>=cxh7 AND cxh6>= cxh8 AND CLOSE<OPEN;

進(jìn)MMM:=CLOSE<EMA(CLOSE,5) AND 進(jìn)QQ;

進(jìn)JJJ:=CLOSE>=EMA(CLOSE,5) AND 進(jìn)QQ;進(jìn)JJ:=cxh6>=cxh7 AND cxh6>=cxh8 AND CLOSE>OPEN;

進(jìn)XX:=cxh8>cxh6 AND cxh8>cxh7;

進(jìn)MM:=cxh7>cxh6 AND cxh7>cxh8;

量AA:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));

買(mǎi)量:=IF(CLOSE>OPEN,量AA*(HIGH-LOW),IF(CLOSE<OPEN,量AA*((HIGH-OPEN)+ (CLOSE-LOW)),VOL/2));

賣(mài)量:=IF(CLOSE>OPEN,0-量AA*((HIGH-CLOSE)+(OPEN-LOW)),IF(CLOSE<OPEN,0- 量AA*(HIGH-LOW),0-VOL/2));

進(jìn)出量:買(mǎi)量+賣(mài)量,NODRAW;

凈量:進(jìn)出量+賣(mài)量,NODRAW;

昨日凈量:=REF(凈量,1);

凈量比:進(jìn)出量/凈量,COLORMAGENTA,NODRAW;額:=AMOUNT/100000000,VOLSTICK,COLORFF00FF;

額cxh1:=AMOUNT/((HIGH-LOW)*2-ABS(CLOSE-OPEN));

流入億:=IF(CLOSE>OPEN,額cxh1*(HIGH-LOW),IF(CLOSE<OPEN,額cxh1*((HIGH-OPEN)+(CLOSE-LOW)),AMOUNT/2))/100000000,COLORRED,NODRAW;

流出億:=IF(CLOSE>OPEN,0-額cxh1*((HIGH-CLOSE)+(OPEN- LOW)),IF(CLOSE<OPEN,0-額cxh1*(HIGH-LOW),0-AMOUNT/2))/100000000,COLORMAGENTA,NODRAW;

差億:=流入億+流出億,COLORFFFF00,NODRAW;凈:=EMA(EMA(差億,2),2),COLOR00FFFF,NODRAW;WWWcxh99COM:=EMA(凈,2);

凈1:=EMA(凈,2);

流:=EMA(凈1,7);

凈流:3*EMA(凈1+流,2),COLORRED,NODRAW;

五日量額比:成交量額/REF(MA(成交量額,5),1),COLORMAGENTA,NODRAW;

跌停:=C<=DTPRICE(REF(CLOSE,1),0.097);

STICKLINE((底>=0) AND 凈買(mǎi)>=0,0,底,0.6,0),LINETHICK2,COLORYELLOW;

STICKLINE(進(jìn)出量<0 AND 凈買(mǎi)<0,0,底,3.2,0),COLOR006600;STICKLINE(進(jìn)出量<0 AND 凈買(mǎi)<0,0,底,2.6,0),COLOR008800;

STICKLINE(進(jìn)出量<0 AND 凈買(mǎi)<0,0,底,1.9,0),COLOR00AA00;STICKLINE(進(jìn)出量<0 AND 凈買(mǎi)<0,0,底,1.1,0),COLOR00CC00;

STICKLINE(進(jìn)出量<0 AND 凈買(mǎi)<0,0,底,0.3,0),COLOR00FF00;STICKLINE(進(jìn)MMM OR 跌停,0,底,0.0,0),COLORGREEN;

STICKLINE(進(jìn)MMM OR 跌停,0,底,3.1,0),COLORFF0000;

STICKLINE(進(jìn)MMM OR 跌停,0,底,1.9,0),COLORFF0000;

STICKLINE(進(jìn)MMM OR 跌停,0,底,0.1,0),COLORFFFF00;STICKLINE(凈買(mǎi)>=0 AND 進(jìn)JJ>=1 AND 底<0,0,底,2.3,0 ),COLOR880088;

STICKLINE(凈買(mǎi)>=0 AND 進(jìn)JJ>=1 AND 底<0,0,底,1.6,0 ),COLORAA00AA;

STICKLINE(凈買(mǎi)>=0 AND 進(jìn)JJ>=1 AND 底<0,0,底,0.8,0 ),COLORCC00CC;

STICKLINE(凈買(mǎi)>=0 AND 進(jìn)JJ>=1 AND 底<0,0,底,0.1,0 ),COLOREE00EE;

STICKLINE(凈買(mǎi)>=0 AND 底>=0 AND 底>=REF(底,1),0,底,3.2,0),COLOR0000BB;

STICKLINE(凈買(mǎi)>=0 AND 底>=0 AND 底>=REF(底,1),0,底,1.3,0),COLOR2233DD;

STICKLINE(凈買(mǎi)>=0 AND 底>=0 AND 底>=REF(底,1),0,底,0.3,0),COLOR6677FF;

STICKLINE(凈買(mǎi)>=0 AND 底>=0 AND 底>=REF(底,1) AND 凈流>=REF(凈流,1),0,底,0.1,0),COLORYELLOW;

STICKLINE((G6>G8 OR (G8<50 AND G3>G6 AND G6>REF(G6,1))) AND 凈買(mǎi)>=0 AND G3>REF(G3,1) AND 底5>REF(底5,1) AND 量,0,底,2.3,0),COLORMAGENTA;

AMV1:G3,COLORRED,LINETHICK2;

AMV2:SMA(G3,2,1),COLORYELLOW,LINETHICK2;

AMV3:SMA(AMV2,2,1),COLORGREEN,LINETHICK2;

使用說(shuō)明

1. RSI5 (相對(duì)強(qiáng)弱指標(biāo))：RSI指標(biāo)用于衡量股票的超買(mǎi)超賣(mài)情況。當(dāng)RSI5的數(shù)值高于70時(shí)，表示股票處于超買(mǎi)狀態(tài)，可能會(huì)出現(xiàn)回調(diào)或反轉(zhuǎn)；當(dāng)RSI5的數(shù)值低于30時(shí)，表示股票處于超賣(mài)狀態(tài)，可能會(huì)出現(xiàn)反彈機(jī)會(huì)。操作建議：在超買(mǎi)時(shí)考慮賣(mài)出或觀望，而在超賣(mài)時(shí)可以考慮買(mǎi)入或觀察反彈機(jī)會(huì)。

2. ADX (平均趨向指標(biāo))：ADX指標(biāo)用于判斷股票的趨勢(shì)強(qiáng)度。當(dāng)ADX的數(shù)值大于25時(shí)，表示股票處于趨勢(shì)行情中，趨勢(shì)較強(qiáng)；當(dāng)ADX的數(shù)值低于20時(shí)，表示股票可能處于盤(pán)整或區(qū)間震蕩。操作建議：在趨勢(shì)較強(qiáng)時(shí)可適當(dāng)追加倉(cāng)位或持有，而在趨勢(shì)弱化或盤(pán)整時(shí)可以選擇觀望或輕倉(cāng)操作。

3. 底 (AV + NEWVOL)：底指標(biāo)通過(guò)綜合考慮RSI5和ADX的數(shù)值，給出買(mǎi)入或賣(mài)出信號(hào)。操作建議：在底指標(biāo)為正且凈買(mǎi)量為正時(shí)，可考慮買(mǎi)入；反之，在底指標(biāo)為負(fù)且凈買(mǎi)量為負(fù)時(shí)，可考慮賣(mài)出。

注：

館內(nèi)各種公式為學(xué)習(xí)編程而保存，實(shí)戰(zhàn)使用前一定要看其中是否有未來(lái)函數(shù)并自己親自測(cè)試成功率，決不能依據(jù)公式名稱的描述和形容去投資，據(jù)此入市造成投資損失由投資者自己承擔(dān)。

發(fā)文不易，如獲益，歡迎贊賞，贊賞必復(fù)！